**Program 3.3** SAS Code for Calculating Standardized Differences between Treated and

Untreated Subjects

/\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*/

/\* Compute standardized differences for each covariate in the matched sample. \*/

/\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*/

proc sort data=long;

by des;

run;

/\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*/

/\* Macro for computing standardized differences for continuous variables. \*/

/\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*/

%macro cont(var=,label=);

proc means mean stddev data=long noprint;

var &var;

by des;

output out=outmean (keep = des mean stddev) mean = mean stddev=stddev;

run;

data des0;

set outmean;

if des = 0;

mean\_0 = mean;

s\_0 = stddev;

keep mean\_0 s\_0;

run;

data des1;

set outmean;

if des = 1;

mean\_1 = mean;

s\_1 = stddev;

keep mean\_1 s\_1;

run;

data newdata;

length label $ 25;

merge des0 des1;

d = (mean\_1 - mean\_0)/ sqrt((s\_1\*s\_1 + s\_0\*s\_0)/2);

d = round(abs(d),0.001);

label = &label;

keep d label;

run;

proc append data=newdata base=standiff force;

run;

%mend cont;

/\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*/

/\* Macro for computing standardized differences for binary variables. \*/

/\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*/

%macro binary(var=,label=);

proc means mean data=long noprint;

var &var;

by des;

output out=outmean (keep = des mean) mean = mean;

run;

data des0;

set outmean;

if des = 0;

mean\_0 = mean;

keep mean\_0;

run;

data des1;

set outmean;

if des = 1;

mean\_1 = mean;

keep mean\_1;

run;

data newdata;

length label $ 25;

merge des0 des1;

d = (mean\_1 - mean\_0)/ sqrt((mean\_1\*(1-mean\_1) + mean\_0\*(1-mean\_0))/2);

d = round(abs(d),0.001);

label = &label;

keep d label;

run;

proc append data=newdata base=standiff force;

run;

%mend binary;

%cont(var=cov\_age,label="Age");

%cont(var=cov\_s\_lensum,label="Length of stents");

%cont(var=cov\_s\_sizemin,label="Stent diameter");

%cont(var=stents,label="Number of stents");

%cont(var=cov\_vesnum,label="Number of vessels");

%binary(var=cov\_male,label="Male sex");

%binary(var=income1,label="Income 1");

%binary(var=income2,label="Income 2");

%binary(var=income3,label="Income 3");

%binary(var=income4,label="Income 4");

%binary(var=income5,label="Income 5");

%binary(var=cov\_hyperten,label="Hypertension");

%binary(var=prevmi\_none,label="Previous MI: none within 365 days of index PCI");

%binary(var=prevmi\_index,label="Previous MI: same day as index PCI");

%binary(var=prevmi\_7days,label="Previous MI: 1-7 days before index PCI");

%binary(var=prevmi\_1year,label="Previous MI: 8-365 days before index PCI");

%binary(var=ccscat\_0,label="CCS Class 0");

%binary(var=ccscat\_1,label="CCS Class I");

%binary(var=ccscat\_2,label="CCS Class II");

%binary(var=ccscat\_3,label="CCS Class III");

%binary(var=ccscat\_4A,label="CCS Class IVA");

%binary(var=ccscat\_4B,label="CCS Class IVB");

%binary(var=ccscat\_4C,label="CCS Class IVC");

%binary(var=ccscat\_4D,label="CCS Class IVD");

%binary(var=cov\_diab\_2cat,label="Diabetes");

%binary(var=cov\_chf,label="CHF");

%binary(var=cov\_pvd,label="PVD");

%binary(var=cov\_copd,label="COPD");

%binary(var=cov\_cerebvd,label="Cerebrovascular disease");

%binary(var=cov\_1ocancer,label="Primary cancer");

%binary(var=cov\_dialysis,label="Renal disease requiring dialysis");

%binary(var=cov\_ccnprevacb,label="Previous CABG surgery");

%binary(var=cov\_ccnprevptca,label="PCI > 1 year before index PCI");

%binary(var=cov\_adhoc,label="Ad hoc procedure");

%binary(var=lesion\_type\_A,label="Lesion Type A");

%binary(var=lesion\_type\_B1,label="Lesion Type B1");

%binary(var=lesion\_type\_B2,label="Lesion Type B2");

%binary(var=lesion\_type\_C,label="Lesion Type C");

proc print data=standiff;

title 'Standardized differences in propensity score matched sample';

run;